Excel

Calculating National Insurance

2009-12-09T02:56:00.002+01:00

Create the cells above and create names for each of the values from the names in the left column.

Two functions are available, one for employee national insurance, one for employer.

The calls are

=NationalInsurance(50000.0,Lower_Earnings_Threshold,Upper_Earnings_Threshold,Class_1,Class_1___4)

=EmployerNationalInsurance(50000.0,Lower_Earnings_Threshold,Class_1___Secondary)

The code for these functions is this


Function NationalInsurance( _
   income As Double, _
   lowerearnings As Double, _
   upperearnings As Double, _
   classonerate As Double, _
   secondaryrate As Double _
   ) As Double
   NationalInsurance = 0#
   If income <= lowerearnings Then        
       Exit Function    
   End If    
   If income <= upperearnings Then        
       NationalInsurance = (income - lowerearnings) * classonerate    
   Else        
       NationalInsurance = (upperearnings - lowerearnings) * classonerate + (income - upperearnings) * secondaryrate    
   End If     
End Function 

Function EmployerNationalInsurance( _
   income As Double, _
   lowerearnings As Double, _
   secondaryrate As Double _
   ) As Double
   EmployerNationalInsurance = 0#
   If income <= lowerearnings Then
       Exit Function
   End If
   EmployerNationalInsurance = (income - lowerearnings) * secondaryrate
End Function

Calculating UK Tax

2009-12-09T02:53:00.003+01:00

With this as a table, the following function call can be made from Excel

=IncomeTax(50000.0,TaxRates)

To calculate the tax paid. TaxRates is the range above.

The code for this is as follows.


Function IncomeTax(income As Double, rates As Range) As Double
    Dim i As Integer
    Dim tax As Double
    tax = 0
    For i = 1 To rates.Rows.Count - 1
        tax = tax + Application.Min(income, rates.Cells(i, 1)) * rates.Cells(i, 2)
        income = Application.Max(0, income - rates.Cells(i, 1))
    Next i
    IncomeTax = tax + income * rates.Cells(rates.Rows.Count, 2)
End Function

2006-08-14T11:26:00.000+02:00

We often are given a chunk of data in Excel that we need to explore. Of course, the first tool you should pull out of your toolbox in cases like this is the trusty PivotTable (it slices, it dices!). But at times we have to dig a little deeper into the toolbox and pull out the in-cell bar chart. Here’s what it looks like.

link

Creating Names

2006-05-04T17:52:00.000+02:00

Here is a better way to create a named range.


ActiveWorkbook.Names.Add 
    Name:="Data", 
    RefersToR1C1:="=" & 
    Worksheets("Data").Cells(1, 1).CurrentRegion.Address(True, True, xlR1C1, False)

The secret is in using the Address method to generate a name that can be used by
the Add method on a names collection.

Why didn't Microsoft allow Excel to do the following


 Range.Name = "Fred"

as an operation?

Amazon.co.uk: Spreadsheet Check and Control: 47 key practices to detect and prevent errors: Books

2006-05-03T11:53:00.000+02:00

Amazon.co.uk: Spreadsheet Check and Control: 47 key practices to detect and prevent errors: Books

Learn how to: increase efficiency by avoiding rework; discover powerful formula auditing techniques; foil attempts to conceal data and formulas from you; reduce worry about costly and embarrassing mistakes; create spreadsheets faster by avoiding wasted time from lack of specification; present results with more confidence knowing that you have checked for errors; benefits to your organisation; ensure data quality and accuracy; protect against formula and operational errors; be able to demonstrate management of material risks; increase controls over spreadsheet based financial reporting; and reduce compliance costs for businesses in regulated sectors.

Buggy spreadsheets: Russian roulette for the corporation | The Register

2006-05-03T11:37:00.000+02:00

Buggy spreadsheets: Russian roulette for the corporation The Register: "How many scenarios can you imagine where a momentary loss of concentration could cost over $1bn? Perhaps a nuclear power station meltdown...or if a currency trader hit a few wrong keys? Well, another possibility is a simple spreadsheet error.
In October 2003, soon after announcing third quarter earnings, Fannie Mae had to restate its unrealised gains, increasing them by $1.2bn. This highly unwelcome outcome was said to stem from 'honest mistakes made in a spreadsheet used in the implementation of a new accounting standard'.
The really, really bad news is that millions of similar errors are almost certainly being made every year, many of them in business-critical financial spreadsheets. Although they are the quintessential end-user tool, spreadsheets of any complexity are just as hard to write and maintain as any other kind of software - if they are to yield consistently accurate results, anyway."

Interesting article with several references to other articles about errors in spreadsheets.

Create Custom Menu Items in Excel VBA

2006-02-16T18:40:00.000+01:00

Create Custom Menu Items in Excel VBA

Returning an array of values

2006-02-01T11:29:00.000+01:00

http://www.cpearson.com/excel/returnin.htm

How to return an array of values in VBA using a range function.

Rule 20: User Name

2005-08-11T17:04:00.000+02:00



  ' Declare for call to mpr.dll.
   Declare Function WNetGetUser Lib "mpr.dll" _
      Alias "WNetGetUserA" (ByVal lpName As String, _
      ByVal lpUserName As String, lpnLength As Long) As Long

   Const NoError = 0       'The Function call was successful

   Sub GetUserName()

      ' Buffer size for the return string.
      Const lpnLength As Integer = 255

      ' Get return buffer space.
      Dim status As Integer

      ' For getting user information.
      Dim lpName, lpUserName As String

      ' Assign the buffer size constant to lpUserName.
      lpUserName = Space$(lpnLength + 1)

      ' Get the log-on name of the person using product.
      status = WNetGetUser(lpName, lpUserName, lpnLength)

      ' See whether error occurred.
      If status = NoError Then
         ' This line removes the null character. Strings in C are null-
         ' terminated. Strings in Visual Basic are not null-terminated.
         ' The null character must be removed from the C strings to be used
         ' cleanly in Visual Basic.
         lpUserName = Left$(lpUserName, InStr(lpUserName, Chr(0)) - 1)
      Else

         ' An error occurred.
         MsgBox "Unable to get the name."
         End
      End If

      ' Display the name of the person logged on to the machine.
      MsgBox "The person logged on this machine is: " & lpUserName

   End Sub

Rule 19: Machine Name

2005-08-11T17:03:00.000+02:00



Private Declare Function GetComputerName Lib "kernel32" _
    Alias "GetComputerNameA" _
    (ByVal lpBuffer As String, nSize As Long) As Long


Function ReturnComputerName() As String
Dim rString As String * 255, sLen As Long, tString As String
    tString = ""
    On Error Resume Next
    sLen = GetComputerName(rString, 255)
    sLen = InStr(1, rString, Chr(0))
    If sLen > 0 Then
        tString = Left(rString, sLen - 1)
    Else
        tString = rString
    End If
    On Error GoTo 0
    ReturnComputerName = UCase(Trim(tString))
End Function

Rule 18: Using DB Code

2005-08-11T12:46:00.000+02:00

Here is an example of using the DB Code



' Load Duration sheet
Sub Load_Duration()
    Dim sqlQry As String
    Dim ds As String
    Dim dbConn As ADODB.Connection
    
    ds = Format(Worksheets("Main").Range("Risk_Date"), "YYYYMMDD")
    sqlQry = "select isin, duration, date from durations where date = '" & ds & "'"
    WSDuration.Range("Duration").ClearContents
    
    Set dbConn = Db.OpenConnection_ODBC(GetDBParams("FASER", "_SERVER"), _
                                        GetDBParams("FASER", "_DB"), _
                                        GetDBParams("FASER", "_USER"), _
                                        GetDBParams("FASER", "_PASSWORD"))
    Call SQLToRangeName(dbConn, sqlQry, WSDuration, "Duration", True)
    
    If WSDuration.Range("Duration").Rows.count < 2 Then 
        AddLogItem ("Load_Duration : Warning - no data retrieved for Duration")
    End If
End Sub

Pretty easy. The parameters are straight forward extracts from a sheet or a parameter file.

Setting up the sql query is easy.

Results go to one sheet.

To further use the results, vlookups are the easy way. That means the first column should be the key for the table. The vlookup is then

=vlookup (key, Duration, 2, FALSE)

Rule 18: Centralise DB code

2005-08-11T12:42:00.000+02:00

Here is some centralised DB access code



Option Explicit

Private Enum ConnectionType
    MSAccess = 0
    Sybase = 1
End Enum

Private liveConnections As Collection


Private Sub AddLiveConnection 
    (
    ByVal key As String, 
    ByRef theConnection As adodb.connection
    )
    Call CheckLiveConnections
    If Trim(key) <> "" _
            And Not (theConnection Is Nothing) _
            And LiveConnectionExists(key) = False _
            And theConnection.State = adodb.adStateOpen _
            Then
        liveConnections.Add theConnection, key
    End If
End Sub

Private Function GetLiveConnection(ByVal key As String) As adodb.connection
    CheckLiveConnections
    If CollectionItemExists(liveConnections, key) Then
        Set GetLiveConnection = liveConnections(key)
    Else
        Set GetLiveConnection = Nothing
    End If
End Function

Private Function LiveConnectionExists(ByVal key As String) As Boolean
    Dim db As adodb.connection
    
    Call CheckLiveConnections
    If CollectionItemExists(liveConnections, key) Then
        Set db = liveConnections(key)
        If db.State = adStateOpen Then
            LiveConnectionExists = True
        Else
            'The connection must have existed, but was not open, so delete it.
            Set db = Nothing
            liveConnections.Remove (key)
        End If
    End If
End Function

Private Sub CheckLiveConnections()
    'Need to check that the liveConnections array exists, as it may have died previously.
    If liveConnections Is Nothing Then
        Set liveConnections = New Collection
    End If
End Sub

Private Function GetDBConnection
    (
    ByVal connType As ConnectionType, 
    ByVal info As String
    ) As adodb.connection
    Dim odbcStr As String
    
    On Error GoTo ErrorHandler
    
    'Open a connection to the database
    Set GetDBConnection = New adodb.connection
    
    Select Case connType
        Case ConnectionType.MSAccess
            'For access databases the info is the file path of the database
            odbcStr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=""" & info & """"
        Case ConnectionType.Sybase
            'For Sybase databases the info is the odbc string
            odbcStr = info & "Driver={SYBASE ASE ODBC Driver};"
    End Select
    
    GetDBConnection.ConnectionString = odbcStr
    GetDBConnection.Open
    
    Exit Function
    
ErrorHandler:
    MsgBox Err.Description
    
End Function

Public Function OpenConnection_Access(ByVal pathMDB As String) As adodb.connection
    On Error GoTo ErrorHandler
    
    Set OpenConnection_Access = GetDBConnection(MSAccess, pathMDB)
    
    Exit Function
    
ErrorHandler:
    MsgBox Err.Description
    
End Function

Public Function OpenConnection_ODBC
    (
    ByVal server As String, 
    ByVal db As String, 
    ByVal user As String, 
    ByVal password As String
    ) As adodb.connection
    On Error GoTo ErrorHandler
    
    Dim odbcString As String
    Dim key As String

    'Build the key for the collection
    key = server & "_" & db & "_" & user
    
    'Return the connection if it exists already
    If LiveConnectionExists(key) Then
        Set OpenConnection_ODBC = GetLiveConnection(key)
    Else
        odbcString = odbcString & "Srvr=" & server & ";"
        odbcString = odbcString & "Database=" & db & ";"
        odbcString = odbcString & "Pwd=" & password & ";"
        odbcString = odbcString & "uid=" & user & ";"
        Set OpenConnection_ODBC = GetDBConnection(Sybase, odbcString)
        Call AddLiveConnection(key, OpenConnection_ODBC)
    End If
    
    Exit Function
    
ErrorHandler:
    MsgBox Err.Description
    
End Function



Public Sub CloseDBConnection(ByRef dbConn As adodb.connection)

    On Error GoTo ErrorHandler
    
    'If there is a connection shut it down.
    If Not (dbConn Is Nothing) Then
        If dbConn.State = adodb.adStateOpen Then
            dbConn.Close
        End If
        Set dbConn = Nothing
    End If
    
    Exit Sub
    
ErrorHandler:
    MsgBox Err.Description
    
End Sub

Private Function SQLRecordset
    (
    ByRef dbConn As adodb.connection, 
    ByVal sql As String
    ) As adodb.Recordset

    On Error GoTo ErrorHandler
    
    Dim rs As adodb.Recordset
    
    If Not (dbConn Is Nothing) Then
        'Open a recordset
        Set rs = New adodb.Recordset
        Call rs.Open(sql, dbConn, adOpenForwardOnly)
        Set SQLRecordset = rs
    Else
        MsgBox "Cannot open recordset when there is no active database connection"
    End If
    
    Exit Function
    
ErrorHandler:
    MsgBox Err.Description
    
End Function

Public Function SQLToArray
    (
    ByRef dbConn As adodb.connection, 
    ByVal sql As String
    ) As Variant

    On Error GoTo ErrorHandler
    
    Dim rs As adodb.Recordset
    
    If Not (dbConn Is Nothing) Then
        'Open a recordset
        Set rs = New adodb.Recordset
        Call rs.Open(sql, dbConn, adOpenDynamic)
        SQLToArray = rs.GetRows()
    Else
        MsgBox "Cannot open recordset when there is no active database connection"
    End If
    
    Exit Function
    
ErrorHandler:
    MsgBox Err.Description
    
End Function

Public Sub SQLToRangeName
    (
    ByRef dbConn As adodb.connection, 
    ByVal sql As String, 
    ByRef WSTarget As Worksheet, 
    ByVal rangeNameTarget As String, 
    ByVal headers As Boolean, 
    Optional ByVal cursorType As adodb.CursorTypeEnum = adodb.CursorTypeEnum.adOpenDynamic
    )
                                
    On Error GoTo ErrorHandler
    
    Dim rs As adodb.Recordset
    Dim rng As Range
    Dim rowCount As Long
    Dim fieldCount As Integer
    
    Set rng = WSTarget.Range(rangeNameTarget)
    
    If Not (dbConn Is Nothing) Then
        'Open a recordset
        Set rs = New adodb.Recordset
        Call rs.Open(sql, dbConn, cursorType)
        
        'Copy the headers if required
        If headers Then
            For fieldCount = 0 To rs.Fields.Count - 1
                rng.Cells(1, fieldCount + 1).Value = rs.Fields(fieldCount).Name
            Next fieldCount
        End If
        
        'Copy all the records
        rowCount = rng.Cells(IIf(headers, 2, 1), 1).CopyFromRecordset(rs)
        
        'Check the sizes for the range
        rowCount = rowCount + IIf(headers, 1, 0)
        If rowCount = 0 Then rowCount = 1
        If fieldCount = 0 Then fieldCount = 1
        
        'Resize the range
        Dim TheSheet As String
        Dim TopLeft As String
        Dim BottomRight As String
        Dim RefersToString As String
            
        TheSheet = rng.Worksheet.Name
        TopLeft = rng.Cells(1, 1).address
        BottomRight = rng.Cells(rowCount, fieldCount).address
        RefersToString = "='" & TheSheet & "'!" & TopLeft & ":" & BottomRight
        Application.Names(rangeNameTarget).refersTo = RefersToString
    Else
        MsgBox "Cannot open recordset when there is no active database connection"
    End If
    
    Exit Sub
    
ErrorHandler:
    MsgBox Err.Description
    
End Sub


Public Function SQLExecute
    (
    ByRef dbConn As adodb.connection, 
    ByVal sql As String
    ) As Long

    On Error GoTo ErrorHandler
    Dim recordsAffected As Long
    
    If Not (dbConn Is Nothing) Then
        'Run the SQL
        Call dbConn.Execute(sql, recordsAffected)
    Else
        MsgBox "Cannot open recordset when there is no active database connection"
    End If
    SQLExecute = recordsAffected
    
    Exit Function
    
ErrorHandler:
    MsgBox Err.Description
    
End Function

Rule 17: Logging

2005-08-11T12:33:00.000+02:00

Two major problems

1. Users are very bad at reporting errors.
2. No one knows what systems attach to particular data sources.

There is a solution that fixes both.

When accessing data, you should go through a common code routine. This can then determine the following

1. spreadsheet name
2. database name
3. database server
4. database user
5. local user
6. local machine
7. timestamp
8. success or failure
9. name of the query

Now, this can all be logged to a very simple central database.

Any failures can be reported on easily. A simple asp website is enough to report.

Now if a database moves, you can tell which spreadsheets need changing.
You know about any errors in extracting data
You know who accesses what data.

Trick 3 - Variation on a theme

2005-07-28T16:37:00.000+02:00

Reiner came up with a nice variation on Trick 2.

We have a spreadsheet that is orthogonal. However, in the first column, in this case we have a trade id.

The trick makes it neat to add a new trade. The event when something is entered in the sheet is there. When a new ISIN is added, the formulas from the row above are copied down automatically.

The alternative is running lots of nasty macros.

Trick 2 - Entering Numbers in Formulas

2005-07-20T11:39:00.000+02:00

Here is a snippet from a sheet. X contains a number, and XX is X squared.

i.e. The formula in cell X is "=X*X"

Now type 10 in cell XX overwriting the formula, and you get this.

X now contains the square root of 10, and XX still contains the formula "=X*X"

What's going on?

Well, there is some code behind what is happening.


Sub Start()
      Application.OnEntry = "Update"
End Sub

Sub Update()
On Error GoTo errorhandler
    With Application.Caller
        If Application.Caller.Address = Range("XX").Address Then
            Range("X") = Sqr(Application.Caller)
            Range("XX").Formula = "=X*X"
        End If
    End With
    Exit Sub
errorhandler:
    Exit Sub
End Sub

First the start macro needs to be run. Typically this would sit in the autoexec macro.

Then when something is entered on the sheet, the Update macro is called. This checks to see if you are overwritting the formula in XX. If it is, it calculates the square root, and repastes the formula back in cell XX.

End result, code that works both ways.

If there is a function such as eval in vba, the square root call could also be parameterised.

Download details: Excel 2003/2002 Add-in: MSN Money Stock Quotes

2005-07-09T11:49:00.000+02:00

Download details: Excel 2003/2002 Add-in: MSN Money Stock Quotes: "This add-in for Excel 2003 and Excel 2002 allows you to get dynamic stock quotes from the MSN� Money� Web site. The tools and features found in Excel are particularly well suited to analyzing financial data such as stocks. This add-in allows you to easily gather and study the stocks of interest to you, refresh your quotes when you want, and readily change or modify the quotes gathered."

Office Tips and Hints Blog

2005-07-09T11:41:00.000+02:00

Office Tips and Hints Blog: "The Data Consolidation technique allows you to compare lists quickly and easily.

With the Consolidation technique, you can identify the number of duplicate entries in two or more lists without using a formula.
(not that it's easier, just that there are no formulas) "

Rule 16: StatusBar

2005-06-24T16:56:00.000+02:00

Use the Status bar to report information back to the user whilst code is being executed.

For example, if several files or database queries are being run, then


Application.StatusBar = "Loading file 1 ..."

will display a message on the status bar.


Application.StatusBar = False

Will remove the value on the status bar.

However, we are then back with the issue of nested calls.

Its much better to create two utility functions, with the call, PushStatusMessage, and PopStatusMessage that creates a stack of status messages.


Private Const MaxStatusMessage As Integer = 100
Dim StatusMessages(MaxStatusMessage) As String
Dim StatusMessageCount As Integer

Public Sub PushStatusMessage(message As String)
    If StatusMessageCount = MaxStatusMessage Then
        MsgBox "Status message stack is full"
        Exit Sub
    End If
    StatusMessages(StatusMessageCount) = message
    StatusMessageCount = StatusMessageCount + 1
    Application.StatusBar = message
End Sub

Public Sub PopStatusMessage()
    If StatusMessageCount = 0 Then
        'MsgBox "Status message stack is empty"
        Exit Sub
    End If
    StatusMessageCount = StatusMessageCount - 1
    If StatusMessageCount = 0 Then
        Application.StatusBar = False
    Else
        Application.StatusBar = StatusMessages(StatusMessageCount - 1)
    End If
End Sub

Public Sub Test()
    PushStatusMessage ("Test 1")
    PushStatusMessage ("Test 2")
    PopStatusMessage
    PopStatusMessage
End Sub

Rule 15: Screen Updating

2005-06-24T16:47:00.000+02:00

There is a flag Application.ScreenUpdating that can be set to True or False.

Setting it to False whilst building up code makes the application run faster.

However, in order to write code where you can nest calls means that each subroutine has to remember the state of the flag, and reset it when you exit the subroutine. If there is an early exit, or exception, the flag will not be restored.

One possible solution is a utility subroutine that keeps a stack of the values. Its certainly easier than maintaining flags by hand.

However, there is another approach. Just set the flag in the button code. That will always be at the top level so only one flag is needed. Just make sure its caught in the case of errors.


Private Sub CommandButton1_Click()
    Dim su As Boolean
    su = Application.ScreenUpdating
    Application.ScreenUpdating = False
On Error GoTo finish
    ' Do some work here
    Application.ScreenUpdating = su
    Exit Sub
finish:
    Application.ScreenUpdating = su
End Sub

Trick 1: Reconciliation

2005-06-21T10:59:00.000+02:00

Quite often there is a need to do quick reconcilliations between two different systems.

Take a simple example. You are converting from system A to system B and need to make sure all the items are loaded into system B, and that a calculated value agrees.

How does one do this in Excel?

First we need to load the data into Excel. This can be done in various ways, but ADODB is probably the best.

The data needs to be loaded in a certain form, and this diagram illustrates what is required.

The first column contains the name of the source system. The second column contains the key we need to use to match. The last column contains the calculated value. We load up all the rows from system A, then append the rows from system B.

When we load the calculated value from the second system, we negate the number. More on this later.

Now we can proceed to phase two. We select all the data, and then build a pivot table from the results. The source goes in the column headers. The key goes in the row, and the calculated value goes in the data area.

The pivot table will now look like this.

So what do we have. Anything with a blank in the A or B column means a missing or extra item. When there are two items, but a non zero grand total for the row, this grand total shows the difference.

1. There is a blank in the B column. That means an item in system A doesn't exist in system B

2. We have an item in both, and a zero grand total. That means a perfect match.

3. We have an item in both, but the values are different. 3 and 3.1 or a difference of 0.1

4. A blank in column A means an item in system B exists, where as it doesn't exists in system A

Its as quick as that.

This shows what happens if you put the key or source in the data area. Normally a key would be a string, so it won't sum the data, it counts it. Here we can quickly see anything with a 1 in the data illustrates a missing value. The grand totals of the columns show the number of items from each source.

If you were doing this as part of a conversion, it pays to automate the process. For example, you could build some macros that download all the data, then build the pivot table.

Once the pivot table is built, you can write a macro that hides the good data, just displaying the bad or vice versa.

If you do this, another enhancement is to add on a name to sign off the differences. Then all you need to do as part of a big bang conversion is to run the reconciliation, filter the good items out. That then needs to be signed off by the business, and filed.

This is probably the best Excel trick I have come across. Its not obvious at all that Excel can do things like this without doing a lot of work.

Thanks Dom!

Rule 14: Give Modules meaningful names

2005-06-20T18:14:00.000+02:00

Module1 is not a meaningful name. Point made.

Rule 13: VBA Formulas versus Worksheet formulas

2005-06-20T18:06:00.000+02:00

Quite often there is a choice. Write a formula in the worksheet, or produce some VBA code. How does one make the decision?

If there is conditional logic, then the first port of call is a VBA function. Its very difficult to read conditional logic in a worksheet formula, and they also tend to be quite long.

If the partial results are meaningful, then put these on the spreadsheet and break the formulas down in their component parts.

For example, if profit and loss is made up of different parts, cash, mark to market, transaction costs, fees etc, then a column for each of the parts makes sense. Then they can be totaled in the profit and loss column. If necessary, the other columns can be hidden. It makes debugging and analysis easier.

Putting the formula into VBA also gives a name to what the formula intends to achieve. ie. =B2+C2+D2 doesn't convey much meaning. =Cash(A2) + MarkToMarket(A2) + TCosts(A2) + Fees(A2) makes a lot more sense, even if you have to dig around for the details.

Putting the formulas into VBA also enables their definition to be in one place and one place only. ie. Code it once, not cut and paste the formula everywhere. The code can then be moved out to an XLA an centralised.

Rule 12: The macro recorder produces bad code

2005-06-20T18:01:00.000+02:00

The macro recorder produces bad code. Cut and paste, select / selection has been covered. It does other things too that aren't particularly good.

For example, it doesn't know about named ranges. As such it uses A1 style references all the time.

These should be cleaned up.

The code is very much a stream of conciousness type of approach to coding. Its much better to put some structure to the code.

Break the macro down into subroutines.

Rename the MacroN name of the recording to something that makes sense.

Remove the select / selection from the code

Remove the copy / paste constructs.

Think about any loops that make the code easier.

What about variables? Should things be declared as variables?

Rule 11: Hungarian Notation is bad

2005-06-20T16:29:00.000+02:00

Its quite easy to show why Hungarian notation is bad, and its a point that is often missed in the religious wars on the subject.

If you were designing a database or even an Excel spreadsheet, it would be an awful spreadsheet if the user had to enter the same number in lots of cells.

The principle that should be followed is to have one cell storing the data and refer to that cell. ie. Store the data once.

Hungarian notation goes against that priciple. Instead of storing the type of something in one place, its stores it everywhere it is used.


Dim icRow as Integer
...
icRow = icRow + 1
...

Here the type, an integer counter is stored and repeated everytime the variable is used instead of once, in the dim statement.

If you want to change the type to a long, you have to change the dim, and everytime its used. If you code is used by others, its a real problem. Just your own code is bad enough.

Instead just do this.


Dim row as Integer 'index to the rows in the range
...
row = row + 1
...

Then you can change the type in once place and one place only.
The intent comes from the comment.

Rule 10: Copy and Paste in VBA is evil

2005-06-20T16:18:00.000+02:00

Just like select and selection, copy and paste in VBA codes is also evil. Its a side effect problem again and it can be avoided.

Here is some typical generated code.


    Range("A13:B23").Select
    Selection.Copy
    Range("A26:B36").Select
    ActiveSheet.Paste

Taking out the select, we still have a problem.


    Range("A13:B23").Copy
    Range("A26:B36").Paste

It still has a side effect of putting some values in the clipboard.

Here is some code that does the job without any side effects.


    Range("A26:B36").value = Range("A13:B23").value

Shorter and side effect free.

It also means the user isn't surprised if they run a macro and then try and paste what they thought was in the clipboard into a new range or cell.